MiscComponent Struct - MiscObject

F4SE Member of: MiscObject Script
Requires F4SE version 0.4.2 or higher.

Represents the Component Data of a MiscItem. This includes a Component and a number designating the quantity.

Syntax

Struct MiscComponent
    Component Object
    int Count
EndStruct

Members

• Object: The Component to use.
• Count: The quantity of this component.

Examples

; Trace miscellaneous 'c_Gold' component
MiscObject:MiscComponent gold = new MiscObject:MiscComponent
gold.Object = c_Gold
gold.Count = 100
Debug.Trace("There is "+gold.Count+" of the '"+gold.Object+"' component")

Scriptname Example extends ScriptObject
import MiscObject

MiscComponent[] Components

Group Components
    Component Property c_Leather Auto Const Mandatory
    Component Property c_Plastic Auto Const Mandatory
    Component Property c_Steel Auto Const Mandatory
EndGroup

Event OnInit()
    {An array of miscellaneous components}
    Components = new MiscComponent[0]

    MiscComponent leather = new MiscComponent
    leather.Object = c_Leather
    leather.Count = 1
    Components.Add(leather)

    MiscComponent plastic = new MiscComponent
    plastic.Object = c_Plastic
    plastic.Count = 1
    Components.Add(plastic)

    MiscComponent steel = new MiscComponent
    steel.Object = c_Steel
    steel.Count = 1
    Components.Add(steel)

    int index = 0
    While (index < Components.Length)
        Debug.Trace("("+index+" of "+Components.Length+") There is "+Components[index].Count+" of the '"+Components[index].Object+"' component")
        index += 1
    EndWhile
EndEvent

See Also

• MiscItem
• Component