GetMiscComponents - MiscObject

F4SE Member of: MiscObject Script
Requires F4SE version 0.4.2 or higher.

Gets the Component Data for this MiscItem as an array of MiscComponent structures.

Syntax

MiscComponent[] Function GetMiscComponents() Native

Parameters

• None

Return Value

An array of MiscComponent structures.

Examples

; Count how many different types of components are used
MiscObject DeskFanOffice01

int count = DeskFanOffice01.GetMiscComponents().Length
If (count == 1)
    Debug.Trace(DeskFanOffice01 + " has one type of component.")
ElseIf (count > 0)
    Debug.Trace(DeskFanOffice01 + " has "+count+" types of component.")
Else
    Debug.Trace(DeskFanOffice01 + " has no components.")
EndIf

Scriptname Example extends ScriptObject
import MiscObject

MiscObject Property DeskFanOffice01 Auto Const Mandatory

Event OnInit()
    {For each miscellaneous component}
    MiscComponent[] components = DeskFanOffice01.GetMiscComponents()
    If (components)
        int index = 0
        While (index < components.Length)
            Debug.Trace("("+index+" of "+components.Length+") There is "+components[index].Count+" of the '"+components[index].Object+"' component")
            index += 1
        EndWhile
    Else
        Debug.Trace(DeskFanOffice01+" has no components.")
    EndIf
EndEvent

Notes

• Do not use these functions on Constructible Object as they will not work. Papyrus defines ConstructibleObject Script as extends MiscObject Script when this is not remotely true internally and F4SE does not support this kind of conversion in code so these are separate functions.

See Also

• MiscItem
• Component
• MiscComponent Struct - MiscObject
• SetMiscComponents - MiscObject